0 | module Control.ANSI.SGR
 1 |
 2 | import Data.List
 3 |
 4 | %default total
 5 |
 6 | public export
 7 | data Color
 8 |   = Black | Red | Green | Yellow | Blue | Magenta | Cyan | White
 9 |   | BrightBlack | BrightRed | BrightGreen | BrightYellow | BrightBlue | BrightMagenta | BrightCyan | BrightWhite
10 |
11 | Cast Color String where
12 |   cast Black = "0"
13 |   cast Red = "1"
14 |   cast Green = "2"
15 |   cast Yellow = "3"
16 |   cast Blue = "4"
17 |   cast Magenta = "5"
18 |   cast Cyan = "6"
19 |   cast White = "7"
20 |   cast BrightBlack = "8"
21 |   cast BrightRed = "9"
22 |   cast BrightGreen = "10"
23 |   cast BrightYellow = "11"
24 |   cast BrightBlue = "12"
25 |   cast BrightMagenta = "13"
26 |   cast BrightCyan = "14"
27 |   cast BrightWhite = "15"
28 |
29 | public export
30 | data Style
31 |   = Bold | Faint | NotBoldOrFaint | Italic
32 |   | SingleUnderline | DoubleUnderline | NoUnderline
33 |   | Striked | NotStriked
34 |
35 | Cast Style String where
36 |   cast Bold = "1"
37 |   cast Faint = "2"
38 |   cast NotBoldOrFaint = "22"
39 |   cast Italic = "3"
40 |   cast SingleUnderline = "4"
41 |   cast DoubleUnderline = "21"
42 |   cast NoUnderline = "24"
43 |   cast Striked = "9"
44 |   cast NotStriked = "29"
45 |
46 | public export
47 | data Blink = Slow | Rapid | NoBlink
48 |
49 | Cast Blink String where
50 |   cast Slow = "5"
51 |   cast Rapid = "6"
52 |   cast NoBlink = "25"
53 |
54 | public export
55 | data SGR
56 |   = Reset
57 |   | SetForeground Color
58 |   | SetBackground Color
59 |   | SetStyle Style
60 |   | SetBlink Blink
61 |
62 | ||| Returns the ANSI escape code equivalent to the list of operations provided.
63 | export
64 | escapeSGR : List SGR -> String
65 | escapeSGR xs = "\x1B[" ++ concat (intersperse ";" (toCode <$> xs)) ++ "m"
66 |   where
67 |     toCode : SGR -> String
68 |     toCode Reset = "0"
69 |     toCode (SetForeground c) = "38;5;" ++ cast c
70 |     toCode (SetBackground c) = "48;5;" ++ cast c
71 |     toCode (SetStyle s) = cast s
72 |     toCode (SetBlink b) = cast b
73 |